This task performs classification for all ENVI Machine Learning model types.
Example
e = ENVI()
RasterFile = Filepath('qb_boulder_msi', Subdir=['data'], $
Root_Dir=e.Root_Dir)
Raster = e.OpenRaster(RasterFile)
ROIFile = Filepath('qb_boulder_roi.xml', Subdir=['data'], $
Root_Dir=e.Root_Dir)
ROI = e.OpenROI(ROIFile)
StatsTask = ENVITask('NormalizationStatistics')
StatsTask.INPUT_RASTERS = Raster
StatsTask.Execute
DataPrepTask = ENVITask('MLTrainingDataFromROIs')
DataPrepTask.INPUT_RASTER = Raster
DataPrepTask.INPUT_ROI = ROI
DataPrepTask.BACKGROUND_LABELS = ['Disturbed Earth', 'Water']
DataPrepTask.NORMALIZE_MIN_MAX = StatsTask.Normalization
DataPrepTask.Execute
TrainTask = ENVITask('TrainExtraTrees')
TrainTask.INPUT_RASTER = DataPrepTask.OUTPUT_RASTER
TrainTask.NUM_ESTIMATORS = 100
TrainTask.Execute
outputModelUri = TrainTask.OUTPUT_MODEL_URI
print, 'Model URI: ' + outputModelUri
outputModel = TrainTask.OUTPUT_MODEL
print, outputModel.Attributes
ClassifyTask = ENVITask('MachineLearningClassification')
ClassifyTask.INPUT_RASTER = Raster
ClassifyTask.INPUT_MODEL = TrainTask.OUTPUT_MODEL
ClassifyTask.Execute
DataColl = e.Data
DataColl.Add, ClassifyTask.OUTPUT_RASTER
DataColl.Add, Raster
View = e.GetView()
Layer = View.CreateLayer(Raster)
Layer = View.CreateLayer(ClassifyTask.OUTPUT_RASTER)
Syntax
Result = ENVITask('MachineLearningClassification')
Input parameters (Set, Get): INPUT_RASTER, INPUT_MODEL, NORMALIZE_MIN_MAX, OUTPUT_RASTER_URI
Output parameters (Get only): OUTPUT_RASTER
Parameters marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Parameters marked as "Get" are those whose values you can retrieve but not set.
Input Parameters
INPUT_RASTER (required)
Specify the raster to classify.
INPUT_MODEL (required)
Specify a trained machine learning model to use for classifying the INPUT_RASTER.
NORMALIZE_MIN_MAX (optional)
Specify the data value that corresponds to 0% and 100% reflectance.
OUTPUT_RASTER_URI (optional)
Specify a string with the fully qualified filename and path to export the associated OUTPUT_RASTER.
- If you set this parameter to an asterisk symbol (*), the output raster will be virtual and not written to disk.
- If you do not specify this parameter, or set it to an exclamation symbol (!), a temporary file will be created.
- If you set it to the hash symbol (#), ENVI creates a file in the temporary directory, but this file will not be deleted when ENVI closes.
Output Parameters
OUTPUT_RASTER
This is a reference to the output raster of filetype ENVI.
Methods
Execute
Parameter
ParameterNames
See ENVI Help for details on these ENVITask methods.
Properties
DESCRIPTION
DISPLAY_NAME
NAME
REVISION
See the ENVITask topic in ENVI Help for details.
Version History
Machine Learning 2.0
|
Introduced |
See Also
ENVIMachineLearningModel