RadiometricCalibration Task

This task calibrates an image to radiance, top-of-atmosphere reflectance, or brightness temperatures. See Radiometric Calibration for a list of sensors and their calibration options. To process a spatial or spectral subset instead of the entire image, use ENVISubsetRaster before calling the ENVITask.

Note: Use the ApplyGainOffset task to apply custom gains and offsets to a raster that will be input to a custom calibration routine. Do not pass the output of the ApplyGainOffset task to the RadiometricCalibration task.

The virtual raster associated with this task is ENVICalibrateRaster.

Example

This example shows how to add custom gain/offset metadata to a QuickBird image, then calibrate it to radiance in units of W/(m2 * sr * µm).

; Start the application

e = ENVI()

; Open an input file

File = Filepath('qb_boulder_msi', Subdir=['data'], $

   Root_Dir=e.Root_Dir)

Raster = e.OpenRaster(File)

; Define gains and offsets for a QuickBird file saved

; to ENVI format

Gains = [0.21044118, 0.10555556, 0.13633803, 0.13754386]

Offsets = [0.0, 0.0, 0.0, 0.0]

Metadata = Raster.Metadata

Metadata.AddItem,'data gain values', Gains

Metadata.AddItem,'data offset values', Offsets

; Process a spectral subset of Band 2

Subset = ENVISubsetRaster(Raster, Bands=[1])

; Get the radiometric calibration task from the catalog of ENVI tasks

Task = ENVITask('RadiometricCalibration')

; Define inputs. Since radiance is the default calibration

; method, we do not need to specify it here.

Task.INPUT_RASTER = Subset

Task.OUTPUT_DATA_TYPE = 'Double'

; Run the task

Task.Execute

; Get the collection of data objects currently available in the Data Manager

DataColl = e.Data

; Add the output to the Data Manager

DataColl.Add, Task.OUTPUT_RASTER

; Display the result

View = e.GetView()

Layer = View.CreateLayer(Task.OUTPUT_RASTER)

Syntax

Result = ENVITask('RadiometricCalibration')

Input parameters (Set, Get): INPUT_RASTER, CALIBRATION_TYPE, SCALE_FACTOR, OUTPUT_DATA_TYPE, OUTPUT_RASTER_URI

Output parameters (Get only): OUTPUT_RASTER

Parameters marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Parameters marked as "Get" are those whose values you can retrieve but not set.

Input Parameters

CALIBRATION_TYPE (optional)

Specify a string indicating the calibration type:

Radiance (default)
Top-of-Atmosphere Reflectance
Brightness Temperature

See the Radiometric Calibration tool instructions for detailed definitions and units for each option.

INPUT_RASTER (required)

Specify a raster on which to perform radiometric calibration.

OUTPUT_DATA_TYPE (optional)

Specify a string indicating the output data type:

Int: 16-bit integer
Float: Floating-point (default)
Double: Double-precision floating point
UInt: 16-bit unsigned integer

OUTPUT_RASTER_URI (optional)

Specify a string with the fully qualified filename and path of the associated OUTPUT_RASTER.

If you do not specify this parameter, or set it to an exclamation symbol (!), ENVI creates a temporary file.
If you set it to the hash symbol (#), ENVI creates a file in the temporary directory, but this file will not be deleted when ENVI closes.

SCALE_FACTOR (optional)

This parameter pertains to radiance only. To output radiance in different units than W/(m2 * sr * µm), enter a floating-point scale factor to get the calibrated image in your desired units. If you do not specify this parameter, the default value scale factor is 1.0 which will yield a radiance image in units of W/(m2 * sr * µm).