This task performs a Spectral Angle Mapper (SAM) supervised classification. SAM is a physically based spectral classification that uses an n-D angle to match pixels to reference spectra. This task requires an input vector or ROI layer from which mean spectra are computed for all of the records.

Use the TrainingClassificationStatistics task to compute the mean spectra from vector layers.

Example

This example uses the TrainingClassificationStatistics task to compute the mean spectra of each record from a polygon shapefile. It passes the mean spectra to the SAM classification task, which creates a classification image from a QuickBird scene.

; Start the application
e = ENVI()
 
; Open an input raster and vector
File1 = Filepath('qb_boulder_msi', Subdir=['data'], $
  Root_Dir=e.Root_Dir)
Raster = e.OpenRaster(File1)
File2 = Filepath('qb_boulder_msi_vectors.shp', Subdir=['data'], $
  Root_Dir=e.Root_Dir)
Vector = e.OpenVector(File2)
 
; Get training statistics
StatTask = ENVITask('TrainingClassificationStatistics')
StatTask.INPUT_RASTER = Raster
StatTask.INPUT_VECTOR = Vector
StatTask.Execute
 
; Get the task from the catalog of ENVITasks
Task = ENVITask('SpectralAngleMapperClassification')
 
; Define inputs
Task.INPUT_RASTER = Raster
Task.MEAN = StatTask.MEAN
 
; Run the task
Task.Execute
 
; Get the collection of data objects currently available in the Data Manager
DataColl = e.Data
 
; Add the output to the Data Manager
DataColl.Add, Task.OUTPUT_RASTER
 
; Display the result
View = e.GetView()
Layer = View.CreateLayer(Task.OUTPUT_RASTER)

See More Examples for a code example that uses mean spectra from ROIs as input to SAM classification.

Syntax

Result = ENVITask('SpectralAngleMapperClassification')

Input parameters (Set, Get): CLASS_COLORS, CLASS_NAMES, INPUT_RASTER, MEAN, OUTPUT_RASTER_URI, OUTPUT_RULE_RASTER_URI, THRESHOLD_ANGLE

Output parameters (Get only): OUTPUT_RASTER, OUTPUT_RULE_RASTER

Parameters marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Parameters marked as "Get" are those whose values you can retrieve but not set.

Input Parameters

CLASS_COLORS (optional)

This is an array of RGB triplets representing the class colors as defined by the input vector.

CLASS_NAMES (optional)

This is a string array of class names as defined by the input vector.

INPUT_RASTER (required)

Specify a raster on which to perform supervised classification.

MEAN (required)

Specify an array of size [number of bands, number of classes], representing the mean spectra from the input training regions. You can use the TrainingClassificationStatistics task to compute the mean spectra.

OUTPUT_RASTER_URI (optional)

Specify a string with the fully qualified filename and path to export the associated OUTPUT_RASTER.

  • If you do not specify this parameter, the OUTPUT_RASTER will not be created.
  • If you set this parameter to an asterisk symbol (*), the OUTPUT_RASTER will be virtual and not written to disk.
  • To force the creation of a temporary file, set this parameter to an exclamation symbol (!).
  • If you set it to the hash symbol (#), ENVI creates a file in the temporary directory, but this file will not be deleted when ENVI closes.

OUTPUT_RULE_RASTER_URI (optional)

Specify a string with the fully qualified filename and path of the associated OUTPUT_RULE_RASTER.

  • If you do not specify this parameter, the OUTPUT_RULE_RASTER will not be created.
  • To force the creation of a temporary file set the parameter to an exclamation symbol (!).
  • If you set it to the hash symbol (#), ENVI creates a file in the temporary directory, but this file will not be deleted when ENVI closes.

THRESHOLD_ANGLE (required)

Specify an array of values in radians between 0 and 1.5708 (π/2). The default value is 1.5708. You can specify a one-element array to use the same threshold value for all classes. Or, specify an n-element array (where n equals the number of classes), with separate threshold values for each class.

Output Parameters

OUTPUT_RASTER

This is a reference to the output raster of filetype ENVI.

OUTPUT_RULE_RASTER

This is a reference to the output rule image of filetype ENVI.

This output will not be generated unless its associated URI input parameter is set.

Methods

Execute

Parameter

ParameterNames

Properties

DESCRIPTION

DISPLAY_NAME

NAME

REVISION

TAGS

More Examples

The following example uses mean spectra from individual ROIs as input to SAM classification. The ROIs represent locations of known mineral types. The input image is an AVIRIS hyperspectral scene of Cuprite, Nevada, USA. The source files are available from our ENVI Tutorials web page. Click the Hyperspectral link to download the .zip file to your machine, then unzip the files. You will be using the files the files CupriteAVIRISSubset.dat and CupriteMineralROIs.xml.

  1. Copy the following code into a new window of the IDL Editor and save it to a file named CupriteSAMExample.pro.
  2. Change the input data paths to the location of the files on your system.
  3. Compile and run the program.
PRO CupriteSAMExample
  COMPILE_OPT IDL2
   
  ; Start the application
  e = ENVI()
   
  ; Select input data
  File = 'CupriteAVIRISSubset.dat'
  CupriteRaster = e.OpenRaster(File)
   
  ROIFile = 'CupriteMineralROIs.xml'
  rois = e.OpenROI(ROIFile)
   
  ; Create a mask that includes the ROIs
  MeanArray = !NULL
   
  For i=0, N_ELEMENTS(rois)-1 DO BEGIN
    ROITask = ENVITask('ROIMaskRaster')
    ROITask.DATA_IGNORE_VALUE = 0
    ROITask.INPUT_MASK_ROI = rois[i]
    ROITask.INPUT_RASTER = CupriteRaster
    ROITask.Execute
   
    ; Compute the mean from each ROI-masked image
    RSTask = ENVITask('RasterStatistics')
    RSTask.INPUT_RASTER = ROITask.OUTPUT_RASTER
    RSTask.Execute
   
    ; Construct an array of mean values from the ROIs
    MeanArray = [[MeanArray], [RSTask.MEAN]]
  EndFOR
   
  ; Run SAM classification
  Task = ENVITask('SpectralAngleMapperClassification')
  Task.INPUT_RASTER = CupriteRaster
  Task.MEAN = MeanArray
  Task.OUTPUT_RASTER_URI = e.GetTemporaryFilename()
  Task.Execute
   
  ; Get the collection of data objects currently available in the Data Manager
  DataColl = e.Data
   
  ; Add the output to the Data Manager
  DataColl.Add, Task.OUTPUT_RASTER
   
  ; Display the result
  View = e.GetView()
  Layer = View.CreateLayer(CupriteRaster)
  roiLayers = !NULL
  FOREACH roi, rois DO $
  roiLayers = [roiLayers, Layer.AddRoi(roi)]
  Layer3 = View.CreateLayer(Task.OUTPUT_RASTER)
END

Version History

ENVI 5.2

Introduced

See Also

ENVITask, TrainingClassificationStatistics Task, MahalanobisDistanceClassification Task, MaximumLikelihoodClassification Task, MinimumDistanceClassification Task, Masking Support in ENVITasks